Excel practice › Excel interview test

Excel test for job interviews: 10 practice exercises with answers

This is a free Excel practice test with answers. You solve 10 exercises in a working spreadsheet in your browser, from a basic total to INDEX/MATCH. No download and no sign-up.

It is not any employer's or test vendor's actual test. It covers the skills such tests commonly list: totals and percentages, IF, conditional sums, lookups, text and dates.

Skip to the 10 exercises ↓

What these tests check

LevelWhat you're asked to doOn this page
BasicTotals, averages, the largest value in a column; a percentage of a totalExercises 1 and 2
IntermediateIF with a limit; a total for one customer (SUMIF, COUNTIF); filling a column from a second table (VLOOKUP or XLOOKUP); cleaning up textExercises 3 to 6
AdvancedA total with two conditions (SUMIFS); a lookup to the left (INDEX/MATCH); working days between two dates; a lookup that may find nothing (IFERROR)Exercises 7 to 10

Job postings and tests differ. Ask the recruiter which version of Excel the test uses and which level it targets. The version matters: XLOOKUP exists in Excel 2021 and later and in Microsoft 365, so on an older version you need VLOOKUP or INDEX/MATCH.

This page practices formulas. It doesn't cover pivot tables, charts or keyboard shortcuts.

Basic: totals, averages and a percentage

Every exercise uses the same made-up data: the March order log of an office-supplies company, with one row per order.

Type the formula in the box and press Enter. Clicking a cell inserts its address. Each answer is checked on the data you see and again on changed data, so a typed-in number won't pass. The answer is under each exercise.

Exercise 1MAX and AVERAGE in one formula

The log lists the eight orders of March. In G2, calculate how far the largest order is above the average order amount.

G2fx
ABCDEFG
1OrderDateCustomerCategoryAmountAbove average
250013/2/2026Acme DentalPaper180
350023/3/2026Northside LawInk210
450033/5/2026Acme DentalFurniture640
550043/9/2026Harbor RealtyPaper120
650053/12/2026Northside LawPaper270
750063/16/2026Harbor RealtyInk140
850073/20/2026Acme DentalInk480
950083/24/2026Lakeview ClinicFurniture360
Show the answer

=MAX(E2:E9)-AVERAGE(E2:E9) gives 340.

MAX returns the largest amount (640) and AVERAGE the mean of the eight (300). A function's result is a number, so you can subtract one from the other. Give both the whole range, not a list of cells: a list is where a row gets left out.

Exercise 2Share of a total

Order 5007 is in row 8. In F8, calculate what share of the month's total that order is. The result is a decimal (0.35 would mean 35%); in Excel you'd then format the cell as a percentage.

F8fx
ABCDEF
1OrderDateCustomerCategoryAmountShare
250013/2/2026Acme DentalPaper180
350023/3/2026Northside LawInk210
450033/5/2026Acme DentalFurniture640
550043/9/2026Harbor RealtyPaper120
650053/12/2026Northside LawPaper270
750063/16/2026Harbor RealtyInk140
850073/20/2026Acme DentalInk480
950083/24/2026Lakeview ClinicFurniture360
Show the answer

=E8/SUM(E2:E9) gives 0.2.

A share is the part divided by the whole: 480 out of 2,400. Before copying this formula down a column, write the total as SUM($E$2:$E$9). Without the $ signs the range moves down one row with each copy, and the shares below the first come out wrong.

Intermediate: IF, conditional totals, lookups and text

Same order log. Two of these exercises bring in a second table, which is where lookups come from: one table has the key, the other has the detail you need.

Exercise 3IF with a calculation

Orders of $300 or more ship free. Smaller orders pay $15 for shipping. In F2, calculate what to bill for order 5001: the amount, plus shipping when it applies.

F2fx
ABCDEF
1OrderDateCustomerCategoryAmountTo bill
250013/2/2026Acme DentalPaper180
350023/3/2026Northside LawInk210
450033/5/2026Acme DentalFurniture640
550043/9/2026Harbor RealtyPaper120
650053/12/2026Northside LawPaper270
750063/16/2026Harbor RealtyInk140
850073/20/2026Acme DentalInk480
950083/24/2026Lakeview ClinicFurniture360
Show the answer

=IF(E2>=300,E2,E2+15) gives 195.

IF returns one of two values, and either one can be a calculation. The mistake to avoid is the limit itself: "$300 or more" is >=, not >. Test your formula in your head with the exact limit before you move on.

Exercise 4Total for one customer

A customer name is typed in G2. In H2, total the amount of that customer's orders.

H2fx
ABCDEFGH
1OrderDateCustomerCategoryAmountCustomerTotal
250013/2/2026Acme DentalPaper180Acme Dental
350023/3/2026Northside LawInk210
450033/5/2026Acme DentalFurniture640
550043/9/2026Harbor RealtyPaper120
650053/12/2026Northside LawPaper270
750063/16/2026Harbor RealtyInk140
850073/20/2026Acme DentalInk480
950083/24/2026Lakeview ClinicFurniture360
Show the answer

=SUMIF(C2:C9,G2,E2:E9) gives 1300.

SUMIF takes the range to test, the value to match and the range to add up, in that order. COUNTIF with the first two arguments counts those orders instead of adding them.

Exercise 5Fill a column from a second table

The small table in F1:G5 says which sales rep handles each customer. In D2, return the rep for the order in row 2.

D2fx
ABCDEFG
1OrderCustomerAmountRepCustomerRep
25001Acme Dental180Acme DentalDana
35002Northside Law210Harbor RealtyPriya
45003Acme Dental640Lakeview ClinicOwen
55004Harbor Realty120Northside LawMarcus
65005Northside Law270
75006Harbor Realty140
85007Acme Dental480
95008Lakeview Clinic360
Show the answer

=VLOOKUP(B2,F2:G5,2,FALSE) gives Dana.

The value to find is the customer in B2, the table is F2:G5 and the rep is its 2nd column. FALSE asks for an exact match. Before copying the formula down, lock the table as $F$2:$G$5. =XLOOKUP(B2,F2:F5,G2:G5) returns the same rep. More on VLOOKUP and XLOOKUP.

Exercise 6Clean up names with TRIM

This contact list was exported from another system with stray spaces before and after the names. You can't see them, but they are there. In D2, build the name as Last, First with no extra spaces.

D2fx
ABCD
1FirstLastCompanyName
2 ReneeOkafor Acme Dental
3 Luis MarquezNorthside Law
4Tanya BrooksHarbor Realty
5 WeiChen Lakeview Clinic
6Omar HaddadAcme Dental
7 GraceLindholm Northside Law
Show the answer

=TRIM(B2)&", "&TRIM(A2) gives Okafor, Renee.

TRIM removes the spaces before and after a text and leaves single spaces between words. & joins the pieces, including the comma and space in quotes. Stray spaces are also a usual reason a lookup returns #N/A on a value that looks right.

Advanced: two conditions, INDEX/MATCH, dates and a lookup that fails

These four are the ones worth doing twice. Each has one detail that decides whether the result is right: an operator joined to a cell, the order of the ranges, which days get counted, what happens when nothing is found.

Exercise 7SUMIFS with a category and a date

In H4, total the orders of the category in G2 that were placed on or after the date in H2.

H4fx
ABCDEFGH
1OrderDateCustomerCategoryAmountCategoryFrom
250013/2/2026Acme DentalPaper180Paper3/9/2026
350023/3/2026Northside LawInk210
450033/5/2026Acme DentalFurniture640Total
550043/9/2026Harbor RealtyPaper120
650053/12/2026Northside LawPaper270
750063/16/2026Harbor RealtyInk140
850073/20/2026Acme DentalInk480
950083/24/2026Lakeview ClinicFurniture360
Show the answer

=SUMIFS(E2:E9,D2:D9,G2,B2:B9,">="&H2) gives 390.

SUMIFS starts with the range to add up, then takes pairs of range and condition. A comparison with a cell is written as text joined to the cell: ">="&H2. With > alone, the order placed on March 9 would be left out.

Exercise 8INDEX/MATCH: who placed the largest order

In G2, return the name of the customer who placed the largest order. The customer column is to the left of the amounts, so VLOOKUP can't do it.

G2fx
ABCDEFG
1OrderDateCustomerCategoryAmountTop customer
250013/2/2026Acme DentalPaper180
350023/3/2026Northside LawInk210
450033/5/2026Acme DentalFurniture640
550043/9/2026Harbor RealtyPaper120
650053/12/2026Northside LawPaper270
750063/16/2026Harbor RealtyInk140
850073/20/2026Acme DentalInk480
950083/24/2026Lakeview ClinicFurniture360
Show the answer

=INDEX(C2:C9,MATCH(MAX(E2:E9),E2:E9,0)) gives Acme Dental.

MAX finds the largest amount, MATCH finds its position in E2:E9 (the 0 means exact match), and INDEX returns the customer at that position in C2:C9. The two ranges have to cover the same rows. =XLOOKUP(MAX(E2:E9),E2:E9,C2:C9) returns the same name where XLOOKUP exists. More on INDEX and MATCH.

Exercise 9Working days between two dates

In D2, count the working days (Monday to Friday) that order 5001 took to arrive, counting both the day it was ordered and the day it was delivered.

D2fx
ABCD
1OrderOrderedDeliveredWorking days
250013/2/20263/10/2026
350023/3/20263/6/2026
450033/5/20263/17/2026
550043/9/20263/13/2026
650053/12/20263/20/2026
750063/16/20263/18/2026
Show the answer

=NETWORKDAYS(B2,C2) gives 7.

NETWORKDAYS counts Monday to Friday from the start date to the end date, both included. Plain subtraction, =C2-B2, counts calendar days and leaves out the first one: it gives 8 here. Read the question for which of the two it wants.

Exercise 10A lookup that may find nothing

Next week's orders. Order 5009 comes from a customer that isn't in the rep table yet. In D2, return the rep for the customer in B2, or the text Unassigned when the customer isn't in the table.

D2fx
ABCDEFG
1OrderCustomerAmountRepCustomerRep
25009Pine Street Vet95Acme DentalDana
35010Harbor Realty230Harbor RealtyPriya
45011Acme Dental410Lakeview ClinicOwen
55012Northside Law150Northside LawMarcus
65013Lakeview Clinic275
75014Acme Dental60
Show the answer

=IFERROR(VLOOKUP(B2,F2:G5,2,FALSE),"Unassigned") gives Unassigned.

IFERROR returns the lookup's result when there is one, and your text when the lookup ends in an error. IFNA is the stricter choice: it only catches #N/A, so other errors stay visible. With XLOOKUP, the fallback text can go in its 4th argument instead.

How to use the time you have

If the test is tomorrow. Do the 10 exercises on this page. For each one you couldn't solve, open the answer, read why it works, then empty the box and type the formula yourself. After that, take the free 10-question Excel test: it uses different data, and it ends with a level and the first topic you missed.

If you have a few days. Work on what you missed. Lesson 1 (cells, SUM, AVERAGE, MAX) and lesson 2 (IF, AND, OR, nested IF) are free, and so are the function pages linked from each answer. The lessons on VLOOKUP, XLOOKUP, SUMIFS and COUNTIFS, INDEX/MATCH and dates are part of Pro: $29 once for all three tracks, or $19 for the Excel track alone. No subscription, and a 14-day refund.

If the posting mentions more than formulas. Pivot tables and keyboard shortcuts are not on this page. They are lesson 9 and lesson 8, also part of Pro.

Applying for a specific kind of job? There is a version of this page for accounting interviews and one for data analyst interviews.

Questions people ask

Is this Excel test for interviews free, and are the answers included?

Yes to both. Every exercise has a Show the answer line under it, with the formula, its result and a short explanation. The page is free and there is nothing to sign up for.

Do I need Excel installed to take this practice test?

No. The spreadsheet on this page runs in your browser, on a computer or a phone. The formulas are the same ones Excel uses, so what you type here is what you would type in Excel. Two differences: the sheet here supports the common functions, not all of Excel, and it shows plain numbers (0.2 where Excel shows 20% once you format the cell).

Is this the same Excel assessment test an employer will give me?

No. This is practice material written for this site, not a copy of any employer's or test company's test. Real tests differ in level, in length and in format. Ask the recruiter three things: which version of Excel the test uses, which level it targets (basic, intermediate or advanced), and whether it is timed.

How long does this Excel interview practice test take?

It has 10 exercises and no timer, so it takes as long as you need. If your real test is timed, do the page once to learn the formulas, then come back and do it again without opening the answers.

Keep going

Ten more questions in a real spreadsheet, from SUM to INDEX/MATCH, on different data. You get a level at the end and the first topic you missed. Free, no sign-up.

Related

Excel test for accounting interviewsExcel interview questions for data analystsVLOOKUP function, with live examplesSUMIFS function, with live examplesINDEX MATCH, with live examplesExcel IF function practiceExcel practice online

Written and tested by Nico, who builds SheetDrill (about). Every formula on this page ran through the engine that checks the exercises before the page was published. Last checked November 2026.