Excel practice › Excel interview test › Accounting
Excel test for accounting interviews: 8 practice exercises with answers
This is a free Excel practice test for accounting and bookkeeping roles, with answers. You solve 8 exercises in a working spreadsheet in your browser: a budget variance, an account lookup and an accounts receivable aging report. No download and no sign-up.
It is not any employer's or test vendor's actual test. It covers the Excel skills that tests for accounting jobs commonly list, on made-up data.
What these tests check
| Level | What you're asked to do | On this page |
|---|---|---|
| Basic | Subtract and divide cells the right way round: a variance, its percentage, the days between two dates | Exercises 1, 2 and 4 |
| Intermediate | An exact-match lookup by account number; nested IF for aging buckets; ROUND to the cent; a month-end date with EOMONTH | Exercises 3, 5, 6 and 7 |
| Advanced | A total with two conditions (SUMIFS): what one customer still owes | Exercise 8 |
Tests differ by employer and by role. Ask the recruiter which version of Excel the test uses and which level it targets. This page practices formulas: it doesn't cover pivot tables or keyboard shortcuts.
Part 1: budget against actual
A small expense report for March, with a budget and an actual figure per account.
Type the formula in the box and press Enter. Clicking a cell inserts its address. Each answer is checked on the data you see and again on changed data, so a typed-in number won't pass. The answer is under each exercise.
In D2, calculate the variance for Travel. On this sheet, variance means actual minus budget, so a positive number is over budget.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Account | Budget | Actual | Variance |
| 2 | Travel | 1200 | 1500 | |
| 3 | Rent | 2400 | 2400 | |
| 4 | Office Supplies | 500 | 575 | |
| 5 | Utilities | 800 | 760 | |
| 6 | Software | 650 | 663 | |
| 7 | Payroll | 18000 | 18360 |
Show the answer
=C2-B2 gives 300.
A variance is one cell minus another. The mistake to avoid is the sign: both ways of subtracting are in use, so check which one the sheet asks for before you write the formula.
The variances are filled in. In E2, calculate the Travel variance as a share of its budget. The result is a decimal (0.1 would mean 10%); in Excel you'd then format the cell as a percentage.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Account | Budget | Actual | Variance | Variance % |
| 2 | Travel | 1200 | 1500 | 300 | |
| 3 | Rent | 2400 | 2400 | 0 | |
| 4 | Office Supplies | 500 | 575 | 75 | |
| 5 | Utilities | 800 | 760 | -40 | |
| 6 | Software | 650 | 663 | 13 | |
| 7 | Payroll | 18000 | 18360 | 360 |
Show the answer
=D2/B2 gives 0.25.
The percentage is the variance divided by the budget, the number that was planned: 300 out of 1,200. =(C2-B2)/B2 is the same calculation without the helper column. The parentheses matter there, because Excel divides before it subtracts.
Part 2: chart of accounts
Account numbers on one side, names on the other. Coding lines to accounts is a lookup.
Three expense lines need their account names. In F2, return the name of the account whose number is in E2, from the chart of accounts in A1:C8.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Account | Name | Type | Account | Name | Amount | |
| 2 | 1000 | Cash | Asset | 6200 | 184.75 | ||
| 3 | 1200 | Accounts Receivable | Asset | 6100 | 2400 | ||
| 4 | 2000 | Accounts Payable | Liability | 5000 | 3120 | ||
| 5 | 4000 | Sales Revenue | Revenue | ||||
| 6 | 5000 | Cost of Goods Sold | Expense | ||||
| 7 | 6100 | Rent Expense | Expense | ||||
| 8 | 6200 | Office Supplies | Expense |
Show the answer
=VLOOKUP(E2,A2:C8,2,FALSE) gives Office Supplies.
The account numbers are the first column of the chart, so VLOOKUP works: find E2 in A2:C8, return column 2, exact match. When a lookup like this returns #N/A on a number you can see in the list, one of the two is usually stored as text: see the #N/A error.
Part 3: accounts receivable
The invoices of a made-up wholesaler. The aging report lists the open ones as of March 20, 2026. Terms: an invoice is due on the last day of the month after the month it was issued.
The report date is in G2. In E2, calculate how many days invoice INV-2041 is past its due date.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Invoice | Customer | Due date | Amount | Days overdue | As of | |
| 2 | INV-2041 | Baker Hardware | 11/30/2025 | 1840.65 | 3/20/2026 | ||
| 3 | INV-2063 | Baker Hardware | 1/31/2026 | 975.34 | |||
| 4 | INV-2070 | Summit Bakery | 1/31/2026 | 640 | |||
| 5 | INV-2084 | Ridgeway Motors | 2/28/2026 | 1420.72 | |||
| 6 | INV-2102 | Summit Bakery | 3/31/2026 | 388.45 | |||
| 7 | INV-2110 | Ridgeway Motors | 3/31/2026 | 1062.18 |
Show the answer
=G2-C2 gives 110.
Excel stores a date as a number of days, so one date minus another is the days between them. Point at the report date in its cell instead of typing it, and lock it as $G$2 before copying the formula down. If the cell shows a date instead of a number, change its format to General.
The days overdue are filled in. In F2, show the aging bucket for the invoice in row 2: Current for 0 days or fewer, 1-30, 31-60, or Over 60.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Invoice | Customer | Due date | Amount | Days overdue | Bucket |
| 2 | INV-2041 | Baker Hardware | 11/30/2025 | 1840.65 | 110 | |
| 3 | INV-2063 | Baker Hardware | 1/31/2026 | 975.34 | 48 | |
| 4 | INV-2070 | Summit Bakery | 1/31/2026 | 640 | 48 | |
| 5 | INV-2084 | Ridgeway Motors | 2/28/2026 | 1420.72 | 20 | |
| 6 | INV-2102 | Summit Bakery | 3/31/2026 | 388.45 | -11 | |
| 7 | INV-2110 | Ridgeway Motors | 3/31/2026 | 1062.18 | -11 |
Show the answer
=IF(E2<=0,"Current",IF(E2<=30,"1-30",IF(E2<=60,"31-60","Over 60"))) gives Over 60.
Each IF handles one limit and passes everything else on to the next, so the limits go in order. Once the first test has taken everything at 0 or below, the second only needs <=30. Put the bucket names in quotes: without them, Excel reads 1-30 as a subtraction. Nested IF is covered on the IF page and in lesson 2, which is free.
Overdue invoices are charged a late fee: the amount times the rate in G2. In E2, calculate the fee for INV-2041 and round it to the cent with ROUND.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Invoice | Customer | Due date | Amount | Late fee | Fee rate | |
| 2 | INV-2041 | Baker Hardware | 11/30/2025 | 1840.65 | 0.02 | ||
| 3 | INV-2063 | Baker Hardware | 1/31/2026 | 975.34 | |||
| 4 | INV-2070 | Summit Bakery | 1/31/2026 | 640 | |||
| 5 | INV-2084 | Ridgeway Motors | 2/28/2026 | 1420.72 | |||
| 6 | INV-2102 | Summit Bakery | 3/31/2026 | 388.45 | |||
| 7 | INV-2110 | Ridgeway Motors | 3/31/2026 | 1062.18 |
Show the answer
=ROUND(D2*G2,2) gives 36.81.
ROUND changes the stored value, not only what the cell shows: 1,840.65 times 2% is 36.813, and ROUND with 2 keeps 36.81. Formatting a cell to two decimals hides the third one but keeps it in the value, which is how a column of fees ends up a cent away from its own total.
This is the full invoice register, with the date each invoice was issued. In F2, calculate the due date of INV-2041: the last day of the month after the month it was issued.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Invoice | Customer | Issued | Amount | Status | Due date |
| 2 | INV-2041 | Baker Hardware | 10/22/2025 | 1840.65 | Open | |
| 3 | INV-2058 | Ridgeway Motors | 11/17/2025 | 2315.56 | Paid | |
| 4 | INV-2063 | Baker Hardware | 12/9/2025 | 975.34 | Open | |
| 5 | INV-2070 | Summit Bakery | 12/19/2025 | 640 | Open | |
| 6 | INV-2084 | Ridgeway Motors | 1/14/2026 | 1420.72 | Open | |
| 7 | INV-2091 | Baker Hardware | 1/27/2026 | 2150 | Paid | |
| 8 | INV-2102 | Summit Bakery | 2/11/2026 | 388.45 | Open | |
| 9 | INV-2110 | Ridgeway Motors | 2/24/2026 | 1062.18 | Open |
Show the answer
=EOMONTH(C2,1) gives 11/30/2025.
EOMONTH returns the last day of a month. The second argument says how many months to move from the start date: 0 for the same month, 1 for the next. It takes care of 28, 30 and 31 days. In Excel the result can show as a plain number until you format the cell as a date.
The register lists paid and open invoices. In H2, total what the customer in G2 still owes: only the invoices with status Open.
| A | B | C | D | E | F | G | H | |
|---|---|---|---|---|---|---|---|---|
| 1 | Invoice | Customer | Issued | Amount | Status | Customer | Open total | |
| 2 | INV-2041 | Baker Hardware | 10/22/2025 | 1840.65 | Open | Baker Hardware | ||
| 3 | INV-2058 | Ridgeway Motors | 11/17/2025 | 2315.56 | Paid | |||
| 4 | INV-2063 | Baker Hardware | 12/9/2025 | 975.34 | Open | |||
| 5 | INV-2070 | Summit Bakery | 12/19/2025 | 640 | Open | |||
| 6 | INV-2084 | Ridgeway Motors | 1/14/2026 | 1420.72 | Open | |||
| 7 | INV-2091 | Baker Hardware | 1/27/2026 | 2150 | Paid | |||
| 8 | INV-2102 | Summit Bakery | 2/11/2026 | 388.45 | Open | |||
| 9 | INV-2110 | Ridgeway Motors | 2/24/2026 | 1062.18 | Open |
Show the answer
=SUMIFS(D2:D9,B2:B9,G2,E2:E9,"Open") gives 2815.99.
SUMIFS starts with the range to add up, then takes one range and one condition per rule: customer equals G2, status equals Open. A row has to meet both to be counted. SUMIF on the customer alone would add the paid invoice too.
How to use the time you have
If the test is tomorrow. Do the 8 exercises on this page. For each one you couldn't solve, open the answer, read why it works, then empty the box and type the formula yourself. Then take the free 10-question Excel test, which ends with a level and the first topic you missed. If there is time left, the general interview test has 10 more exercises with answers.
If you have a few days. Work on what you missed. Lesson 1 (cells, SUM, AVERAGE, MAX) and lesson 2 (IF, AND, OR, nested IF) are free, and so are the function pages linked from each answer. The lessons on VLOOKUP, SUMIFS and COUNTIFS and dates, including EOMONTH, are part of Pro: $29 once for all three tracks, or $19 for the Excel track alone. No subscription, and a 14-day refund.
If the posting mentions pivot tables. They are not on this page. Lesson 9 practices them and is also part of Pro.
Questions people ask
Is this Excel test for an accounting interview free, with answers?
Yes. Every exercise has a Show the answer line under it, with the formula, its result and a short explanation. The page is free and there is nothing to sign up for.
Do I need Excel installed for this Excel skills test for accountants?
No. The spreadsheet on this page runs in your browser. The formulas are the same ones Excel uses, so what you type here is what you would type in Excel. One difference: the sheet shows plain numbers, with no currency or percentage formatting.
Is this the Excel test an accounting employer will give me?
No. This is practice material written for this site, on made-up invoices and accounts. It is not a copy of any employer's or test company's test. Ask the recruiter which version of Excel the test uses, which level it targets, whether it is timed, and whether it includes pivot tables, which this page does not practice.
How long does this accounting Excel practice test take?
It has 8 exercises and no timer, so it takes as long as you need. If your real test is timed, do the page once to learn the formulas, then do it again without opening the answers.