Excel practice › Excel functions › NETWORKDAYS

NETWORKDAYS in Excel: working days between two dates

NETWORKDAYS counts the working days between two dates: every Monday to Friday in the period, with the start date and the end date both included. For a task that runs from Monday 5/4/2026 to Friday 5/8/2026, =NETWORKDAYS(B2,C2) returns 5.

Weekends are always left out. Holidays are left out only if you list their dates in a range and pass it as the third argument.

Skip to the 3 exercises ↓

Syntax

=NETWORKDAYS(start_date, end_date, [holidays])

start_date
The first day of the period. It is counted, if it's a working day.
end_date
The last day of the period. It is counted too.
holidays
Optional: a range of dates to leave out of the count, like the days the company is closed. Without it, only Saturdays and Sundays are skipped.
Live exampleMonday to Friday
D2fx
ABCDEFG
1TaskStartEndWork daysHolidayDate
2Site survey5/4/20265/8/20265Memorial Day5/25/2026
3Permits5/11/20265/29/2026Juneteenth6/19/2026
4Framing6/1/20267/10/2026July 4 (observed)7/3/2026
5Electrical7/13/20267/24/2026Labor Day9/7/2026
6Inspection8/31/20269/11/2026

How Excel counts

  1. It goes through every day from start_date to end_date, the two ends included.
  2. It skips every Saturday and Sunday.
  3. If you gave it a holidays range, it also skips every date found there.
  4. It returns how many days are left.

So a task that starts and ends on the same weekday counts 1, not 0: =NETWORKDAYS(B2,B2) is 1. If you want the days after the start, subtract 1 from the result.

The three ways it goes wrong

Each of these is live below. Fix the formula in the box and watch the cell.

1. Subtracting the dates. A subtraction counts calendar days, weekends included:

Live exampleCalendar days, not working days
D3fx
ABCDEFG
1TaskStartEndWork daysHolidayDate
2Site survey5/4/20265/8/2026Memorial Day5/25/2026
3Permits5/11/20265/29/202618Juneteenth6/19/2026
4Framing6/1/20267/10/2026July 4 (observed)7/3/2026
5Electrical7/13/20267/24/2026Labor Day9/7/2026
6Inspection8/31/20269/11/2026

2. Forgetting the holidays. NETWORKDAYS knows nothing about holidays. A Monday is a working day to it, also when it's Memorial Day:

Live exampleA holiday counted as a working day
D3fx
ABCDEFG
1TaskStartEndWork daysHolidayDate
2Site survey5/4/20265/8/2026Memorial Day5/25/2026
3Permits5/11/20265/29/202615Juneteenth6/19/2026
4Framing6/1/20267/10/2026July 4 (observed)7/3/2026
5Electrical7/13/20267/24/2026Labor Day9/7/2026
6Inspection8/31/20269/11/2026

3. A holidays range with something else in it. The range must hold dates and nothing else. Include the names next to them, or the header, and the result is an error:

Live example#VALUE!: names inside the holidays range
D3fx
ABCDEFG
1TaskStartEndWork daysHolidayDate
2Site survey5/4/20265/8/2026Memorial Day5/25/2026
3Permits5/11/20265/29/2026#VALUE!Juneteenth6/19/2026
4Framing6/1/20267/10/2026July 4 (observed)7/3/2026
5Electrical7/13/20267/24/2026Labor Day9/7/2026
6Inspection8/31/20269/11/2026

Two more things about the holidays range. A holiday that falls on a Saturday or Sunday changes nothing, since that day wasn't counted anyway: July 4, 2026 is a Saturday, which is why this list has the Friday the company closes instead. And when you copy the formula down a column, lock the range with dollar signs, $G$2:$G$5, so it doesn't slide down with each row.

Practice: 3 exercises

Type the formula in the box, press Enter. Clicking a cell inserts its address. Each answer is checked on the data you see and again on changed data, so a typed-in value won't pass.

Exercise 1Working days of a task

In D5, count the working days of the Electrical task, from its start in B5 to its end in C5. No holiday falls inside it.

D5fx
ABCDEFG
1TaskStartEndWork daysHolidayDate
2Site survey5/4/20265/8/2026Memorial Day5/25/2026
3Permits5/11/20265/29/2026Juneteenth6/19/2026
4Framing6/1/20267/10/2026July 4 (observed)7/3/2026
5Electrical7/13/20267/24/2026Labor Day9/7/2026
6Inspection8/31/20269/11/2026
Show the answer

=NETWORKDAYS(B5,C5) gives 10.

Monday 7/13 to Friday 7/24 is two full working weeks: 10 days. A subtraction would say 11, the calendar days after the start.

Exercise 2Leave out the holidays

The Framing task runs from 6/1/2026 to 7/10/2026, and the company is closed on some of those days. In D4, count its working days, leaving out the holidays listed in G2:G5.

D4fx
ABCDEFG
1TaskStartEndWork daysHolidayDate
2Site survey5/4/20265/8/2026Memorial Day5/25/2026
3Permits5/11/20265/29/2026Juneteenth6/19/2026
4Framing6/1/20267/10/2026July 4 (observed)7/3/2026
5Electrical7/13/20267/24/2026Labor Day9/7/2026
6Inspection8/31/20269/11/2026
Show the answer

=NETWORKDAYS(B4,C4,G2:G5) gives 28.

There are 30 weekdays from June 1 to July 10. Two holidays fall on weekdays inside the period, June 19 and July 3, which leaves 28. Memorial Day and Labor Day are in the list too, but outside these dates, so they change nothing.

Exercise 3Over budget or not

Each task has a budget of working days in column D. In E3, show Over if the Permits task takes more working days than its budget, and OK otherwise. The holidays in G2:G5 are not working days.

E3fx
ABCDEFG
1TaskStartEndBudget daysStatusHolidays
2Site survey5/4/20265/8/202655/25/2026
3Permits5/11/20265/29/2026126/19/2026
4Framing6/1/20267/10/2026307/3/2026
5Electrical7/13/20267/24/2026109/7/2026
6Inspection8/31/20269/11/20269
Show the answer

=IF(NETWORKDAYS(B3,C3,G2:G5)>D3,"Over","OK") gives Over.

NETWORKDAYS returns 14 for this task: 15 weekdays minus Memorial Day. 14 is more than the budget of 12, so IF returns Over. NETWORKDAYS gives a number like any other, so it can sit inside IF or a calculation.

Questions people ask

Does NETWORKDAYS include the start date and the end date?

Yes, both, when they are working days. Monday to Friday of the same week is 5, and a single weekday counted from itself to itself is 1. For the working days that have passed since the start, subtract 1.

How do I exclude holidays from NETWORKDAYS?

List the holiday dates in a column and pass that range as the third argument: =NETWORKDAYS(B2,C2,$G$2:$G$5). The range must hold only dates. The dollar signs keep it in place when the formula is copied down.

What if the weekend isn't Saturday and Sunday?

Use NETWORKDAYS.INTL, which has an extra argument to say which days of the week are the weekend. NETWORKDAYS itself always skips Saturday and Sunday. The sheets on this page don't run NETWORKDAYS.INTL.

How do I find the date a number of working days after a start date?

That's the reverse question, and it has its own function: =WORKDAY(start_date, days, [holidays]) returns the date that many working days after the start, skipping weekends and the holidays you list.

Keep going

Lesson 7 is seven drills on a design studio's invoices: days between two dates, month-end due dates with EOMONTH, business days with NETWORKDAYS, and TEXT for month labels and amounts inside a sentence. It's part of Pro ($29 once for all three tracks, or $19 for the Excel track alone). Lessons 1 and 2 and the skills test are free.

Related

EOMONTH function, with live examplesDATEDIF function, with live examplesIF function, with live examples#VALUE! error in Excel: meaning and fixesExcel date functions practice (Pro)Excel functions with live examplesExcel practice online

Written and tested by Nico, who builds SheetDrill (about). Every formula on this page ran through the engine that checks the exercises before the page was published. Checked against: Microsoft Support: NETWORKDAYS function, WORKDAY function. Last checked November 2026.