Excel practice › Excel functions › CONCAT and &

CONCAT and & in Excel: join text from several cells

CONCAT and the & operator join values into one text. With a first name in A2 and a last name in B2, =A2&" "&B2 gives Dana Whitfield, and so does =CONCAT(A2," ",B2).

Neither adds anything between the pieces: every space, comma or dash is yours to put in, in quotes. And dates and numbers join as the raw value the cell stores, not the way the cell shows it: a date turns into a number like 46090 unless you wrap it in TEXT.

Skip to the 3 exercises ↓

Syntax

=CONCAT(text1, [text2], …) or =text1 & text2

text1
The first thing to join: text in quotes, a cell, or a range of cells.
[text2], …
More things to join, in the order you list them. Microsoft's limit is 253 text arguments.
&
The operator that joins the value on its left to the value on its right: =A2&B2. It gives the same result as CONCAT with those two arguments.
Live exampleFirst and last name in one cell
G2fx
ABCDEFG
1FirstLastCityStateHiredQuotaFull name
2DanaWhitfieldTulsaOK3/9/202648500Dana Whitfield
3MarcusOyelaranBoiseID1/12/202652000
4IreneKowalczykFresnoCA2/2/202661250
5TobiasReyesMaconGA4/20/202645000
6PriyaVenkatAkronOH5/18/202657500

How Excel reads it

  1. It takes the pieces from left to right and glues them together exactly as they are.
  2. Text you type goes in double quotes: " " is a space, ", " is a comma and a space. Cell addresses take no quotes.
  3. A separator is a piece like any other. Leave it out and the two values touch.

The result is text, also when every piece was a number.

The two ways it goes wrong

Both are live below. Fix the formula in the box and watch the cell.

1. Nothing between the pieces. CONCAT accepts a range, which is quick to write, but it has no argument for a separator:

Live exampleA range, joined with nothing in between
G2fx
ABCDEFG
1FirstLastCityStateHiredQuotaFull name
2DanaWhitfieldTulsaOK3/9/202648500DanaWhitfield
3MarcusOyelaranBoiseID1/12/202652000
4IreneKowalczykFresnoCA2/2/202661250
5TobiasReyesMaconGA4/20/202645000
6PriyaVenkatAkronOH5/18/202657500

2. A date or a number loses its format. A join uses what the cell stores, not what it shows. A date is stored as a serial number, so this is what comes out:

Live exampleA date joined as a number
G2fx
ABCDEFG
1FirstLastCityStateHiredQuotaNote
2DanaWhitfieldTulsaOK3/9/202648500Hired 46090
3MarcusOyelaranBoiseID1/12/202652000
4IreneKowalczykFresnoCA2/2/202661250
5TobiasReyesMaconGA4/20/202645000
6PriyaVenkatAkronOH5/18/202657500

Numbers behave the same way. A cell formatted as currency shows $48,500 and joins as 48500; a cell that shows 40% joins as 0.4. TEXT puts the format back: ="Quota: "&TEXT(F2,"$#,##0") gives Quota: $48,500.

Practice: 3 exercises

Type the formula in the box, press Enter. Clicking a cell inserts its address. Each answer is checked on the data you see and again on changed data, so a typed-in value won't pass.

Exercise 1Last name, first name

For a sorted contact list: in G2, build the name in the form Whitfield, Dana from the last name in B2 and the first name in A2.

G2fx
ABCDEFG
1FirstLastCityStateHiredQuotaSort name
2DanaWhitfieldTulsaOK3/9/202648500
3MarcusOyelaranBoiseID1/12/202652000
4IreneKowalczykFresnoCA2/2/202661250
5TobiasReyesMaconGA4/20/202645000
6PriyaVenkatAkronOH5/18/202657500
Show the answer

=B2&", "&A2 gives Whitfield, Dana.

Three pieces: the last name, a comma and a space in quotes, the first name. =CONCAT(B2,", ",A2) is the same formula written with the function.

Exercise 2First name and last initial

For name badges: in G2, build the first name, a space, the first letter of the last name and a period, like Dana W.

G2fx
ABCDEFG
1FirstLastCityStateHiredQuotaBadge
2DanaWhitfieldTulsaOK3/9/202648500
3MarcusOyelaranBoiseID1/12/202652000
4IreneKowalczykFresnoCA2/2/202661250
5TobiasReyesMaconGA4/20/202645000
6PriyaVenkatAkronOH5/18/202657500
Show the answer

=A2&" "&LEFT(B2,1)&"." gives Dana W..

LEFT(B2,1) returns the first letter of the last name, and the period is one more piece in quotes. Functions and quoted text can be mixed freely in a join.

Exercise 3A sentence with a date in it

For a welcome note: in G2, build Dana Whitfield, hired Mar 9, 2026 from A2, B2 and the date in E2. The date's format code is "mmm d, yyyy".

G2fx
ABCDEFG
1FirstLastCityStateHiredQuotaNote
2DanaWhitfieldTulsaOK3/9/202648500
3MarcusOyelaranBoiseID1/12/202652000
4IreneKowalczykFresnoCA2/2/202661250
5TobiasReyesMaconGA4/20/202645000
6PriyaVenkatAkronOH5/18/202657500
Show the answer

=A2&" "&B2&", hired "&TEXT(E2,"mmm d, yyyy") gives Dana Whitfield, hired Mar 9, 2026.

TEXT turns the date into the text Mar 9, 2026 before it's joined. Without it, the join would use what the cell stores: 46090.

Questions people ask

What is the difference between CONCAT, CONCATENATE and &?

They all join text. CONCAT is the newer function: it replaces CONCATENATE and also accepts ranges like A2:C2. CONCATENATE is still there for compatibility with older workbooks. & is the operator form: =A2&" "&B2 and =CONCAT(A2," ",B2) give the same result.

How do I add a space or a comma between two cells?

Put it in the formula as its own piece, in double quotes: =A2&" "&B2 for a space, =B2&", "&A2 for a comma and a space. Excel adds nothing by itself.

How do I join a whole range with commas?

CONCAT can't: it has no separator argument. Use TEXTJOIN, which takes the separator first: =TEXTJOIN(", ",TRUE,A2:A8). The TRUE tells it to skip empty cells.

Why does a date turn into a number when I join it to text?

Because a date is stored as a serial number, and a join uses the stored value, not the format the cell shows. Wrap the date in TEXT with the format you want: =A2&" "&TEXT(B2,"mm/dd/yy").

Keep going

SheetDrill has no lesson on text functions yet. One drill of lesson 7 (dates and TEXT, part of Pro) joins text with & and TEXT. The free skills test is ten questions in a real spreadsheet, from the basics to INDEX/MATCH. No sign-up.

Related

TEXT function, with live examplesLEFT, RIGHT and MID functions, with live examplesTRIM function, with live examples#VALUE! error in Excel: meaning and fixesExcel date functions practice (Pro)Excel functions with live examplesExcel practice online

Written and tested by Nico, who builds SheetDrill (about). Every formula on this page ran through the engine that checks the exercises before the page was published. Checked against: Microsoft Support: CONCAT function, Combine text and numbers, TEXTJOIN function, TEXT function. Last checked November 2026.